dcfg/CMakeLists.txt

cmake_minimum_required(VERSION 3.10)

project(DCFG C)

set(CMAKE_C_STANDARD 99)
set(CMAKE_C_STANDARD_REQUIRED ON)
set(CMAKE_C_EXTENSIONS OFF)

option(DCFG_PTHREAD_SUPPORT "Enable pthreads support" ON)
option(DCFG_POSIX_SUPPORT   "Enable POSIX support"    ON)
option(DCFG_BUILD_PROGRAMS  "Build DCFG example programs" ON)

find_package(Threads)

set(SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}/src)
set(INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/include)

# Shared library
add_library(${PROJECT_NAME}_shared SHARED ${SRC_DIR}/dcfg.c)
target_include_directories(${PROJECT_NAME}_shared PUBLIC ${INCLUDE_DIR})
set_target_properties(${PROJECT_NAME}_shared PROPERTIES OUTPUT_NAME "dcfg")

# Static library
add_library(${PROJECT_NAME}_static STATIC ${SRC_DIR}/dcfg.c)
target_include_directories(${PROJECT_NAME}_static PUBLIC ${INCLUDE_DIR})
set_target_properties(${PROJECT_NAME}_static PROPERTIES OUTPUT_NAME "dcfg")

# Common settings for both libraries
foreach(TARGET ${PROJECT_NAME}_shared ${PROJECT_NAME}_static)
	if(DCFG_PTHREAD_SUPPORT)
		find_package(Threads REQUIRED)
		target_link_libraries(${TARGET} PRIVATE Threads::Threads)
		target_compile_definitions(${TARGET} PRIVATE DCFG_PTHREAD_SUPPORT)
	endif()
	if(DCFG_POSIX_SUPPORT)
		target_compile_definitions(${TARGET} PRIVATE DCFG_POSIX_SUPPORT)
	endif()

	if(MSVC)
		target_compile_options(${TARGET} PRIVATE /W4 /permissive-)
	else()
		target_compile_options(${TARGET} PRIVATE -Wall -Wextra -pedantic -Werror -Wno-newline-eof -Wno-language-extension-token)
	endif()

	if(NOT MSVC)
		target_link_libraries(${TARGET} PRIVATE m)
	endif()
endforeach()

# Install libraries
install(TARGETS ${PROJECT_NAME}_shared ${PROJECT_NAME}_static DESTINATION lib)
install(DIRECTORY ${INCLUDE_DIR}/ DESTINATION include)

# Build example programs
if(DCFG_BUILD_PROGRAMS)
	set(PROGRAMS_DIR ${CMAKE_CURRENT_SOURCE_DIR}/programs)
	file(GLOB PROGRAM_SOURCES "${PROGRAMS_DIR}/*.c")

	foreach(PROG_SRC ${PROGRAM_SOURCES})
		get_filename_component(PROG_NAME ${PROG_SRC} NAME_WE)
		add_executable(${PROG_NAME} ${PROG_SRC})
		target_include_directories(${PROG_NAME} PRIVATE ${INCLUDE_DIR})
		target_link_libraries(${PROG_NAME} PRIVATE ${PROJECT_NAME}_shared)
		if(DCFG_PTHREAD_SUPPORT)
			target_link_libraries(${PROG_NAME} PRIVATE Threads::Threads)
		endif()
		if(MSVC)
			target_compile_options(${PROG_NAME} PRIVATE /W4 /permissive-)
		else()
			target_compile_options(${PROG_NAME} PRIVATE -Wall -Wextra -pedantic -Werror -Wno-newline-eof -Wno-language-extension-token)
		endif()
		install(TARGETS ${PROG_NAME} DESTINATION bin)
	endforeach()
endif()